Lomohome.com :: 괴발자 모근원 :: Lomohome.com

Applescript 로 파일이동을 편하게

내가끄적인글/프로그래밍 2014. 1. 14. 13:47

맥미니를 이용하여 홈서버를 구축하여, CCTV, 웹하드, FTP, 토렌트 다운로드 및 DLNA 등의 서비스를 돌리고 있습니다.

토렌트 다운로드는 많이 알려진 방법대로, Dropbox 의 특정폴더에 torrent 시드파일을 넣으면 uTorrent 에서 땡겨서 다운로드를 받게 만들어두었습니다.

이렇게 하면 외부 어디서든 Dropbox 에 시드파일만 올린다면 집의 서버가 알아서 다운로드를 시작하겠지요.

저는 Request Download 파일이라는 드랍박스 폴더를 만들고, 해당 폴더에 torrent 파일이나 각종 파일들을 다 던져 두면 알아서 파일의 확장자를 가지고 알맞는 폴더로 던져주는 AppleScript 를 이용하고 있습니다.

여기서는 제가 쓰는 AppleScript 의 일부를 보여주고, 대강의 사용법을 알려드리겠습니다.

이 포스팅에서 쓰이는 시나리오는 다음과 같습니다.

1. Request Download 라는 폴더는 torrent 시드파일과, smi, srt 등의 자막파일이 올라올수 있습니다.

2. 토렌트 시드파일은 uTorrent 에서 땡겨가면서 삭제합니다. 토렌트 다운로드가 완료되면 Downloads 라는 폴더에 저장합니다.

3. smi, srt 확장자를 가진 파일은 AppleScript 를 통하여 바로 Downloads 폴더로 옮겨갑니다.

4. Downloads 폴더에 들어간 smi, srt 파일들은 또한 AppleScript 를 통하여 같은 이름을 가진 폴더로 들어갑니다.

먼저 첨부된 스크립트 파일을 확인해주세요.

MoveFileByExt.scpt

moveSubtitleToEachFolder.scpt

내용은 다음과 같습니다. 간략한 설명을 첨부하였습니다.

다운받은 스크립트를 더블클릭하여 경로 등, 자신의 환경에 맞게 수정해주세요.

MoveFileByExt.scpt (이건 Request Download 폴더에 걸 폴더액션 스크립트입니다. 자막파일을 Downloads 로 옮기는거에요.)

--자막확장자들, 리스트 형태, Request Download 폴더에 들어온 파일중 자막파일을 Downloads 로 옮긴다.
property subtitleExtList : {"srt", "smi"} 
-- 5초마다 한번씩 체크 (파일이 다운로드 중일때)
property myDelay : 5
-- 이부분은 옮겨갈 자신의 폴더 경로로 수정해주세요.
property myDownloadFoler : (POSIX file "/Volumes/mossoExt3T_1/Downloads") as alias

on adding folder items to this_folder after receiving these_items
	tell application "Finder"
		repeat with i from 1 to number of items in these_items
			set downloadedFile to item i of these_items --다운로드 된 파일
			
			set the theFileInfo to the info for downloadedFile --파일에서 정보를 추출

set oldFileSize to 0 --처음엔 파일사이즈를 0으로 하고,
			set fileSize to the size of theFileInfo --파일 정보의 파일사이즈.
			repeat while fileSize is not equal to oldFileSize
				set oldFileSize to fileSize
				delay myDelay
				set the theFileInfo to the info for downloadedFile
				set fileSize to the size of theFileInfo
			end repeat --5초(myDelay)마다 마지막 파일사이즈와 현재 파일사이즈를 비교해서 변화가 없을때까지 루프, (다운로드 중이라면 파일사이즈가 계속 증가)

if the name extension of the theFileInfo is in the subtitleExtList then --파일 확장자가 자막파일리스트에 있는지 확인 (srt, smi)
				-- move downloadedFile to myDownloadFoler --이상하게 move가 잘 작동안해서, 카피후 지우는 걸로..
				duplicate file downloadedFile to folder myDownloadFoler with replacing --자막파일을 다운로드 폴더로 카피
				delay myDelay --조금 쉬었다가,
				delete file downloadedFile --원본파일 삭제
				
			end if
		end repeat
	end tell
end adding folder items to

moveSubtitleToEachFolder.scpt (이건 Downloads 폴더에 걸 폴더 스크립트입니다. 자막파일을 같은이름의 폴더로 옮기는거에요.)

property subtitleExtList : {"srt", "smi"} --마찬가지로 자막파일들을 대상으로 작업

property myDelay : 5 --5초마다 딜레이

on adding folder items to this_folder after receiving these_items
	tell application "Finder"
		repeat with i from 1 to number of items in these_items --Downloads 폴더의 모든내용 (파일, 폴더) 대상으로 실행합니다.
			
			set downloadedFile to item i of these_items --목적파일
			
			if kind of (info for downloadedFile) is "folder" then --파일인지, 폴더인지 구분
				set isFolder to true
			else
				set isFolder to false
			end if
			
			
			if isFolder then
				--대상폴더가 자막파일보다 나중에 추가 된 경우.
				set {name:theName, container:theContainer} to downloadedFile --폴더에서 이름과, 소속된 위치를 가져옵니다.
								
				repeat with y from 1 to number of items in subtitleExtList --같은이름의 자막파일이 있는지 체크해봅니다
					set exte to item y of subtitleExtList --smi, srt 루프를 돌면서 하나씩..
					set theFile to theName & "." & exte --폴더이름과 자막 확장자를 합쳐서 해당 파일이 있는지 체크해볼겁니다.
					
					try
						if (exists file theFile of theContainer) then --만약 AA 라는 폴더가 만들어졌다면, aa.srt , aa.smi 가 있는지 체크합니다.
							
							if (exists folder downloadedFile) then --폴더가 만들어졌으니 당연히 true 이겠지만...
								
								duplicate file theFile of theContainer to folder downloadedFile with replacing --자막파일을 만들어진 폴더로 옮깁니다.
								delay myDelay
								delete file theFile of theContainer --카피한후 원본 삭제
								
							end if
							
						end if
					end try
					
				end repeat
				
				
				
				
			else
				--자막파일이 대상폴더 이후에 추가되면 자막을 폴더로 옮겨준다.
				
				set the theFileInfo to the info for downloadedFile --자막파일 정보를 가져옵니다.
				
				set oldFileSize to 0 --위의 스크립트와 마찬가지로, fully downloaded 되었는지 체크..
				set fileSize to the size of theFileInfo
				repeat while fileSize is not equal to oldFileSize
					set oldFileSize to fileSize
					delay myDelay
					set the theFileInfo to the info for downloadedFile
					set fileSize to the size of theFileInfo
				end repeat

if the name extension of the theFileInfo is in the subtitleExtList then --자막파일을 옮기기 시작합니다.
					
					set {name:theName, name extension:theExtension, container:theContainer} to downloadedFile
					if theExtension is not "" then
						set theName to text 1 thru -((count theExtension) + 2) of theName --name 을 가져오면 확장자까지 한번에 가져옵니다. 분리해낼게요
						set theExtension to "." & theExtension
					end if --파일의 정보를 가져와 변수 theName 에는 이름만, theExtension 에는 확장자, theContainer 에는 소속폴더가 들어갑니다.

try
						if (exists folder theName of theContainer) then --자막파일과 같은 이름의 폴더가 있는지 검사합니다.
							duplicate file downloadedFile to folder theName of theContainer with replacing --폴더로 자막파일을 카피하구요..
							delay myDelay
							delete file downloadedFile --원본삭제
						end if
					end try

end if
				
			end if
			
			
		end repeat
	end tell
end adding folder items to

스크립트 파일을 수정했으면, (다른 확장자를 추가해도 되고, 목적폴더를 여러개 만들어서 if 문을 추가해도 되구요..)

파인더 위의 메뉴바중 [이동] 메뉴에서 [옵션] 키를 누른상태로 라이브러리로 갑니다.

라이브러리 - Scripts - Folder Action Scripts 폴더안에다가 스크립트 파일을 넣어줍니다. (폴더 없으면 만드셔요)

그리고 드랍박스의 Request Download 폴더에서 우클릭, 서비스 - 폴더 적용 스크립트 설정을 클릭합니다.

먼저 이곳에 자막파일이 들어오면 Downloads 폴더로 옮길거에요~

이런 창이 뜨는데 아까 라이브러리 Folder Action Scripts 에 넣어둔 스크립트가 뜰거에요.

MoveFileByExt.scpt 스크립트를 선택합니다.

그럼 위와같이 적용이 됩니다.

그다은, Downloads 폴더에도 스크립트를 걸어줍니다. 이번엔 자막파일을 같은이름의 폴더로 옮기는 스크립트를 걸었어요~

스크립트 설정을 마치고 테스트를 해봤습니다.

Downloads 밑에 AA라는 폴더를 만들고 aa.smi 파일을 Request Download 폴더에 넣어봤더니

Downloads 폴더로 먼저 옮겨간후, Downloads 밑의 AA 까지 잘 옮겨가는것을 확인할수 있습니다.

아래스크린샷은 먼저 Request Download -> Downloads 로 aa.smi 가 옮겨가는 장면,

그리고 AA 폴더를 가만히 보고 있자니..

aa.smi 가 AA 폴더까지 최종적으로 옮겨갔습니다.

아직 저도 AppleScript 를 제대로 공부해본건 아니고, 구글링을 해서 이것저것 짬뽕해서 만들다보니 뭐가 뭔진 잘 모르겠는데요,

조금 공부해보면 파일관리에 굉장히 유용한 방법인것 같습니다. 주기적으로 폴더를 다른곳으로 백업한다던가 하는 스크립트도 짜볼수 있겠구요 (rsync 이용)

'내가끄적인글 > 프로그래밍' 카테고리의 다른 글

BMW 목적지 전송 단축어(숏컷) for 카카오맵, 네이버지도 (43)	2018.09.27
일정위젯 앱 3년만의 업데이트 (62)	2015.09.02
[OpenSource?] iOS 사전앱 InDic 소스 공개 (39)	2013.12.30
[iOS App] InDic - 간단하고 빠른 사전어플 (124)	2013.10.21
[Sencha] Sencha Touch (1.1) 을 이용한 간단한 RSS Reader (0)	2013.05.28
[OpenSource?] iOS 일정목록 (Events List)앱 소스 공개. (10)	2013.03.08

Posted by 모근원

Lomohome.com :: 괴발자 모근원

'전체 글'에 해당되는 글 394건

Applescript 로 파일이동을 편하게

'내가끄적인글 > 프로그래밍' 카테고리의 다른 글

Category

Tag

Recent posts

Recent Comment

Recent Trackback

Archive

Link

Calendar

티스토리툴바

« 2024/11 »
일	월	화	수	목	금	토
					1	2
3	4	5	6	7	8	9
10	11	12	13	14	15	16
17	18	19	20	21	22	23
24	25	26	27	28	29	30